Ersetzt alle Instanzen einer angegebenen Zeichenfolge durch eine neue Zeichenfolge.

REPLACE(Zeichenfolge; alter_Text; neuer_Text)
Name Typ Beschreibung
Zeichenfolge

Zeichen

 Der Wert, in dem Zeichen ersetzt werden sollen.
alter_Text

Zeichen

Die zu ersetzende Zeichenfolge. Die Suche unterscheidet zwischen Groß- und Kleinschreibung.
neuer_Text Zeichen Der Text, mit dem der Wert von alter_Text ersetzt werden soll.

Zeichen.

Einfache Beispiele

Gibt „a12345efg“ zurück:

REPLACE("abcdefg"; "bcd"; "12345")

Gibt „Rd.“ zurück:

REPLACE("Straße"; "Straße"; "Str.")

Gibt „ac“ zurück:

REPLACE("abc"; "b"; "")

Weiterführende Beispiele

Bestimmte Zeichen entfernen

Verwenden Sie REPLACE( ), um eine bestimmte Zeichenfolge aus einer Quellzeichenfolge zu entfernen, indem Sie sie durch eine leere Zeichenfolge ("") ersetzen.

Gibt „1234 Scott“ zurück:

REPLACE("1234 Scott rd."; "rd."; "")

Anpassung der Feldlänge

Wenn neuer_Text („ABC“) länger als alter_Text („X“) ist, wird die Feldlänge der sich ergebenden Zeichenfolge automatisch angehoben, damit der erste Ersatz aufgenommen werden kann:

Gibt „9ABC9“ zurück, wobei die Feldlänge von 3 auf 5 Zeichen angehoben wurde:

REPLACE("9X9"; "X"; "ABC")

Die Feldlänge wird bei weiteren Ersetzungen nicht angehoben. Es kann daher dazu kommen, dass Inhalte abgeschnitten werden, wenn das Feld nicht lang genug ist, um alle neuen Zeichen aufzunehmen.

Gibt „9ABC9A“ zurück:

REPLACE("9X9X"; "X"; "ABC")

Um ein Abschneiden zu vermeiden, können Sie die Länge der Zeichenfolge mit der BLANKS( )-Funktion oder literalen Leerzeichen vergrößern.

Gibt „9ABC9ABC“ zurück:

REPLACE("9X9X" + BLANKS(2); "X"; "ABC")
REPLACE("9X9X" + "  "; "X"; "ABC")

Wenn die sich ergebende Zeichenfolge kürzer als Zeichenfolge ist, wird die sich ergebende Zeichenfolge mit Leerzeichen aufgefüllt, damit dieselbe Feldlänge erhalten bleibt.

Gibt „9X9  “ zurück:

REPLACE("9ABC9"; "ABC"; "X")

Funktionsweise

Die REPLACE( )-Funktion ersetzt jede Instanz einer vorhandenen Zeichenfolge mit einer neuen Zeichenfolge.

Gibt „1234 Scott Road“ zurück:

REPLACE("1234 Scott rd."; "rd."; "Road")

Wann Sie REPLACE( ) verwenden sollen

Verwenden Sie REPLACE( ), um Datenfelder mit nicht konsistentem Format zu normalisieren, wie beispielsweise Adressfelder, oder um ungültige Informationen in unzureichend bearbeiteten Feldern zu ersetzen. Funktionen wie Duplikate überprüfen bzw. Tabellen zusammenfügen oder verbinden erfordern Daten in normalisierter oder standardisierter Form, um richtig ausgeführt werden zu können.

Beachtung der Groß- und Kleinschreibung

Bei der REPLACE( )-Funktion wird zwischen Groß- und Kleinschreibung unterschieden. Wenn Sie "STR." in alter_Text angeben und die Werte in Zeichenfolge aus Kleinbuchstaben bestehen, wird der Wert von neuer_Text nicht eingefügt, da keine Übereinstimmungen gefunden werden.

Wenn die Möglichkeit besteht, dass in der Zeichenfolge sowohl Groß- als auch Kleinschreibung verwendet wurden, müssen Sie zuerst die Funktion UPPER( ) Funktion verwenden, um alle Zeichen in Großbuchstaben zu konvertieren.

Gibt „1234 SCOTT ROAD“ zurück:

REPLACE(UPPER("1234 Scott rd."); "RD."; "ROAD")

Vor unbeabsichtigten Ersetzungen schützen

Wenn Sie Ihren REPLACE( )-Ausdruck formulieren, sollten Ihnen sämtliche Instanzen von alter_Text in der Zeichenfolge bewusst sein, damit Sie keine unbeabsichtigten Ersetzungen vornehmen.

Gibt „645 RichaRoad Road“ zurück, weil die letzten beiden Zeichen von „Richard“ „rd“ sind:

REPLACE("645 Richard rd  "; "rd"; "Road")

Indem Sie ein Leerzeichen vor und nach dem Wert in alter_Text einfügen (" rd "), verhindern Sie, dass die Funktion Instanzen ersetzt, bei denen „rd“ innerhalb eines Begriffs vorkommt, da diese Instanzen nicht über führende Leerzeichen verfügen.

Gibt „645 Richard Road“ zurück:

REPLACE("645 Richard rd  "; " rd "; " Road")