Dans ce dernier tutoriel sur les fonctions Analytics, nous ferons une synthèse de tout en utilisant des variables avec un certain nombre de fonctions dans un script accomplissant une tâche concrète.

Ce que le script fait

Cet exemple de script permet à un utilisateur exécutant le script d'appliquer un filtre date sur une table Analytics comportant un champ date, puis de regrouper les enregistrements par mois inclus dans le filtre.

Ce script combine les opérations déjà expliquées dans les précédents tutoriels.

Comment les fonctions s'associent au script

Avec un seul script, un rédacteur de scripts Analytics peut utiliser plusieurs fonctions pour effectuer toute une gamme de tâches, petites mais importantes, qui contribueront à l'analyse globale des données réalisée par le script.

Inclure une fonction dans un script ne change pas la façon dont celle-ci fonctionne. Dans les scripts, les fonctions se comportent de la même façon que lorsque vous les testez de manière isolée dans la ligne de commande Analytics.

Activités suggérées

• Examiner le script

  Examinez l'exemple de script en bas du tutoriel. Les scripts Analytics sont exécutés dans l'ordre, ligne par ligne. Vous pouvez donc procéder séquentiellement et lire chaque COMMENT pour avoir une idée générale de ce que la logique du script est en train de faire.

  Les lignes COMMENT ne font pas partie de la logique du script et ne s'exécutent donc pas.

• Comprendre ce que les fonctions font

  Accordez une attention particulière aux fonctions contenues dans le script. Celles-ci sont surlignées en marron. Reportez-vous au tableau situé au-dessus du script pour plus de détails sur les petites tâches effectuées par chaque fonction.

  Si vous avez terminé les précédents tutoriels sur les fonctions, la plupart des fonctions du script et leurs tâches vous seront familières.

• Exécuter le script

  Une fois que vous maîtrisez le script et les fonctions qu'il contient, copiez-collez-le dans Analytics et exécutez-le pour voir comment l'interactivité du script fonctionne.

Comment exécuter l'exemple de script dans Analytics

1. Ouvrez un projet dans Analytics contenant une ou plusieurs tables avec des champs date.

   Exemple de projet.ACL contient plusieurs tables avec des champs date.

2. Créez un nouveau script vide :
   1. Dans le Navigateur, cliquez avec le bouton droit de la souris sur un dossier ou sur l'entrée de projet située au plus haut niveau Nouveau > Script.
   2. Copiez-collez l'intégralité du script ci-dessous dans le nouveau script dans l'Éditeur de script.
   3. Enregistrez le projet.
3. Cliquez sur Exécuter pour exécuter le script.
4. La boîte de dialogue vous demande de sélectionner une table et un champ date, de spécifier les dates de début et de fin ainsi que de sélectionner un champ de sous-total numérique.

Exemple de script : filtrer et regrouper les enregistrements

L'exemple de script fait principalement deux choses :

• il filtre les enregistrements dans une table par dates, à l'aide des dates que vous précisez
• il regroupe par mois les enregistrements inclus dans le filtre

Ne vous inquiétez pas si vous ne comprenez pas toute la syntaxe du script. Le plus important est de voir les différentes fonctions Analytics en action dans un script.

Un COMMENT avant chaque partie de syntaxe du script vous explique de manière simple ce qui se passe.

Les fonctions utilisées dans l'exemple de script

L'objectif de chaque fonction utilisée dans cet exemple est décrit ci-dessous.

Dans le script, les fonctions sont surlignées en marron.

Fonction dans le script	Objectif
DATE( )	Convertit les variables MIN1 et MAX1 du type de données DateHeure en type de donnes Caractère. Le type de données Caractère est nécessaire pour afficher le contenu des variables dans une chaîne de texte dans une boîte de dialogue. MIN1 et MAX1 sont des variables système créées automatiquement par la commande STATISTICS. Elles contiennent la date la plus ancienne et la data la plus récente dans le champ date que vous avez sélectionné.
ALLTRIM( )	Nettoie les espaces supplémentaires entourant ces dates quand elles sont affichées dans la boîte de dialogue.
CTOD( )	Convertit les variables v_date_début et v_date_fin du type de données Caractère en type de données DateHeure. Ce type de données est exigé pour soustraire ou comparer des dates.
CTOD( )	Convertit les variables v_date_début et v_date_fin du type de données Caractère en type de données DateHeure pour qu'elles soient cohérentes avec la variable v_champ_date. Tous les paramètres de la fonction BETWEEN doivent être du même type de données.
BETWEEN( )	Filtre le champ date sur la base des dates de début et de fin que vous avez spécifiées.
MONTH( )	Extrait la partie mois de toutes les dates du champ date sous forme de nombre.
CMOY( )	Extrait la partie mois de toutes les dates du champ date sous forme de valeur de caractère.

Exemple de script : filtrer les enregistrements par date et regrouper les enregistrements filtrés par mois.

COMMENT
Ce script vous permet d'appliquer un filtre date sur une table Analytics comportant un champ date, puis de regrouper par mois les enregistrements trouvés.
END

COMMENT Vous invite à sélectionner une table dans le projet Analytics.
ACCEPT "Sélectionner une table avec un champ date :" FIELDS "xf" TO v_nom_table

COMMENT Ouvre la table sélectionnée.
OPEN %v_nom_table%

COMMENT Vous invite à sélectionner un champ date dans la table.
ACCEPT "Sélectionner un champ date :" FIELDS "D" TO v_champ_date

COMMENT Identifie la date la plus récente et la date plus ancienne dans le champ date sélectionné.
STATISTICS ON %v_champ_date%

COMMENT Affecte la date la plus récente et la date la plus ancienne aux variables. Les variables sont utilisées pour afficher la plage de dates existante dans la boîte de dialogue où vous indiquez les dates de début et de fin pour le filtre date. Il est plus facile de spécifier les dates des filtres si vous savez de quelle plage de date il retourne.
ASSIGN v_date_min = ALLTRIM(DATE(MIN1; "AAAAMMJJ"))
ASSIGN v_date_max = ALLTRIM(DATE(MAX1; "AAAAMMJJ"))

COMMENT Vous invite à définir la date de début et la date de fin pour le filtre date.
DIALOG (DIALOG TITLE "Dialogue utilisateur" WIDTH 484 HEIGHT 153 ) (BUTTONSET TITLE "&OK;&Annuler" AT 370 12 DEFAULT 1 ) (TEXT TITLE "Spécifier une date de début :" AT 12 16 ) (EDIT TO "v_date_début" AT 156 12 DEFAULT "AAAAMMJJ" ) (TEXT TITLE "Spécifier une date de fin :" AT 12 52 ) (EDIT TO "v_date_fin" AT 156 48 DEFAULT "AAAAMMJJ" ) (TEXT TITLE "Plage de dates dans la table :" AT 12 88 ) (TEXT TITLE "%v_date_min%   à  %v_date_max%" AT 156 88 )

COMMENT Affiche un avertissement si le filtre date spécifié par l'utilisateur est d'une durée supérieure à 1 an.
IF CTOD(v_date_fin) - CTOD(v_date_début) > 365 OR CTOD(v_date_début) - CTOD(v_date_fin) > 365 DIALOG (DIALOG TITLE "Dialogue utilisateur" WIDTH 469 HEIGHT 100 ) (BUTTONSET TITLE "&OK;&Annuler" AT 348 8 DEFAULT 1 ) (TEXT TITLE "La plage de dates dépasse 1 an. Les regroupements par mois peuvent inclure des enregistrements datant de plus d'un an." AT 12 28 WIDTH 326 HEIGHT 33 ) (TEXT TITLE "Attention" AT 12 8 )

COMMENT Affiche un avertissement si la date de début spécifiée par l'utilisateur est ultérieure à la date de fin.
IF CTOD(v_date_début) > CTOD(v_date_fin) DIALOG (DIALOG TITLE "Dialogue utilisateur" WIDTH 469 HEIGHT 100 ) (BUTTONSET TITLE "&OK;&Annuler" AT 348 8 DEFAULT 1 ) (TEXT TITLE "La date de début est après la date de fin. Les enregistrements entre les deux dates sont inclus." AT 12 28 WIDTH 326 HEIGHT 33 ) (TEXT TITLE "Attention" AT 12 8 )

COMMENT Applique le filtre date à la table et au champ que vous avez sélectionnés.
SET FILTER TO BETWEEN(%v_champ_date%; CTOD(%v_date_début%); CTOD(%v_date_fin%))

COMMENT Vous invite à sélectionner un champ de sous-total.
ACCEPT "Sélectionner un champ numérique pour le sous-total de chaque mois :" FIELDS "N" TO v_champ_sous_total

COMMENT Regroupe la table par mois et sort les résultats dans une nouvelle table.
SUMMARIZE ON MONTH(%v_champ_date%) SUBTOTAL %v_champ_sous_total% OTHER CMOY(%v_champ_date%, 9) TO "%v_nom_table%_par_mois.FIL" OPEN PRESORT

Et ensuite ?

Si vous avez terminé tous les tutoriels des rubriques Utilisation des fonctions et Utilisation avancée des fonctions, bravo ! Vous avez désormais une connaissance solide du fonctionnement des fonctions Analytics dans Analytics dans son ensemble.

Voici quelques suggestions pour aller plus loin :

• Continuez d'explorer
  • Jetez un œil au Top 30 des fonctions Analytics pour accéder à une liste des fonctions Analytics les plus fréquemment utilisées dans Analytics, accompagnées d'exemples.
  • Rechercher et filtrer à l'aide des fonctions Analytics fournit de nombreux exemples d'utilisation des fonctions Analytics pour des recherches et un filtrage puissants et efficaces des données dans les tables.
  • Parcourez l'ensemble des Fonctions Analytics. Familiarisez-vous avec tout ce que les fonctions peuvent faire.
• N'oubliez pas les fonctions

  Quand vous êtes confronté à une difficulté dans vos analyses de données dans votre travail Analytics, demandez-vous si une fonction ou une combinaison de plusieurs fonctions ne pourrait pas vous aider.

  Avec une analyse de données utilisant des commandes Analytics, la majeure partie du challenge consistera en la préparation des données pour l'analyse. Les fonctions, seules ou en combinaison, sont cruciales dans la préparation.