Trabajar con variables en ACLScript

Al escribir un script en Analytics, con frecuencia es necesario tener en cuenta valores que cambian o varían. Por ejemplo:

• Configuración del script Usted desea contar con una forma sencilla de personalizar valores en la lógica de un script, como los nombres de una tabla o un campo, sin que sea necesario actualizar cada instancia de un valor

• Entrada de los usuarios Cuando los usuarios ejecutan un script, desean personalizar los valores de entrada, como los rangos de fechas o las cantidades que representan un umbral

• Almacenamiento temporal La lógica de un script requiere que se almacene de manera temporal un valor que se actualiza de forma continua a medida que el script avanza, como un contador o un total acumulado

Las variables se usan para estos y otros fines.

¿Qué es una variable?

Podemos imaginar las variables como un contenedor con nombre que almacena un valor que puede cambiar. El valor puede cambiar, pero el nombre de la variable no lo hace. Como creador del script, usted utiliza el nombre fijo de la variable a lo largo de toda la lógica del script. Al ejecutar el script, este no procesa el nombre de la variable, sino que accede al valor actualmente almacenado en la variable y lo procesa.

En el ejemplo siguiente, v_fecha_de_inicio y v_fecha_de_finalización son nombres de variables, y las fechas son los valores que contienen las variables.

Ventajas de las variables

Es posible usar variables en lugar de valores literales a lo largo de un script. Al reemplazar los nombres de tabla, nombres de campo, valores de texto, números y fechas reales por variables que hacen referencia a estos elementos, se incrementa notablemente la flexibilidad del script. En lugar de escribir un script que solo funciona en una situación muy específica, puede escribir un script que se puede utilizar en una cantidad ilimitada de situaciones.

¿Cómo y dónde se pueden usar las variables?

Al igual que los elementos literales a los cuales hacen referencia, las variable se pueden crear, renombrar, actualizar, eliminar, usar en cálculos y en una variedad de expresiones, exportar y extraer. En otras palabras, se pueden utilizar en cualquier lugar en el que el elemento literal resultaría válido.

¿Cómo se crea una variable?

Puede crear una variable con un comando de Analytics: el comando ASSIGN o uno de varios otros comandos. En general, el comando se incluye en un script, pero también puede crear una variable manualmente introduciendo el comando ASSIGN en la línea de comandos de Analytics.

ASSIGN v_fecha_de_inicio = `20210101`
ASSIGN v_fecha_de_finalización = `20210331`

Mostrar variables en un proyecto de Analytics

Al trabajar con variables, es sumamente útil poder ver las variables que existen en un proyecto de Analytics y sus valores actuales. Existen dos métodos para poder mostrar las variables y sus valores:

• la ficha Variables

• el comando DISPLAY VARIABLES

La ficha Variables

La ficha Variables del Navegador, hace un seguimiento de la creación de variables y la asignación de valores a las variable en tiempo real. La ficha de solo lectura muestra los nombres, los tipos de datos y los valores actuales de todas las variables de un proyecto de Analytics. Los nombres se indican en orden alfabético.

Si recorre un script línea por línea, las variables definidas en el script o las variables generadas por el sistema aparecen en la ficha Variables en el momento de su creación. Si la variable ya existe, el valor se actualiza de forma dinámica, según la lógica del script. (En el Editor de scripts, use la opción Paso para recorrer un script).

Poder ver exactamente qué cambios se están realizando con las variables del script, a medida que estos ocurren, es una herramienta de diagnóstico importante. Esta capacidad le permite detectar errores en el script que podrían ser difíciles de encontrar si solo se examinara la sintaxis del script.

Si ejecuta un script, se muestran todos los cambios asociados con las variables en la ficha Variables cuando se llega a un salto o cuando finaliza el script.

El comando DISPLAY VARIABLES

El comando DISPLAY VARIABLES muestra los nombres, los tipos de datos y los valores actuales de todas las variables de un proyecto de Analytics. Los nombres aparecen en el orden cronológico inverso según el momento de creación de la variable o de la actualización más reciente.

DISPLAY nombre_variable devuelve la información asociada a una única variable.

Puede usar el comando DISPLAY VARIABLES de dos maneras diferentes:

• Estado actual de las variables del proyecto Escriba DISPLAY VARIABLES en la línea de comandos y presione Intro.

  En la pantalla se muestran todas las variables del proyecto y sus valores actuales en orden cronológico inverso.

• Estado de las variables del proyecto en diferentes lugares de un script Agregue DISPLAY VARIABLES a un script en el lugar o los lugares del script en los que desee captar el estado de las variables del proyecto. También puede usar un punto de quiebre pare este fin. La diferencia es que un punto de quiebre detiene la ejecución del script, mientras que el comando DISPLAY VARIABLES no lo hace.

  Una vez que se complete el script, haga clic en la entrada DISPLAY VARIABLES correspondiente del registro de comandos. En la pantalla, se muestra en orden cronológico inverso el estado de las variables del proyecto en el lugar del script que usted especificó.

Ocho cosas que debe saber acerca de las variables de ACLScript

Si está familiarizado con otros lenguajes de programación o creación de scripts, entonces ya estará familiarizado con las variables y sus muchos usos. A continuación, se describen las principales características de las variables de ACLScript.

Si recién se inicia en la creación de scripts y variables, la siguiente información tendrá más sentido una vez que comience a trabajar con variables.

1.  Una variable se crea automáticamente al asignar un valor

2.  Existen distintos métodos para crear una variable

3.  El tipo de datos de una variable se especifica automáticamente

4.  Los nombres de las variables son flexibles y cuentan con algunas restricciones

5.  Una variable tiene un alcance global

6.  Una variable continúa existiendo hasta que se cierra el proyecto de Analytics

7.  Las variables se pueden eliminar de forma explícita

8.  Las variables del sistema se crean automáticamente por medio de algunos comandos de Analytics.

1.  Una variable se crea automáticamente al asignar un valor

Una variable se crea (declara) automáticamente al asignar un valor inicial a la variable con nombre. La asignación de un valor inicial a una variable también se conoce como "inicialización de una variable".

En el siguiente ejemplo, la variable v_tabla_de_entrada se crea automáticamente al utilizar el comando ASSIGN para asignar el valor "Trans_Cp" a la variable. En otras palabras, la creación de la variable y la asignación de un valor a la variable (declaración e inicialización) ocurren en un solo paso

ASSIGN v_tabla_de_entrada = "Trans_Cp"

¿Cuándo y dónde debe crear una variable?

Puede crear una variable en cualquier parte de un script, siempre que la creación de la variable sea anterior a su primer uso.

Lo más conveniente es crear todas las variables de entrada del usuario y las variables de configuración del script al inicio del script. Si sigue este enfoque, un usuario puede introducir todos los valores de entrada necesarios al inicio del script y después dejar que se ejecute el script. También puede estar seguro de que todas las variables de configuración del script necesarias se encuentren en una ubicación única y organizada, al principio del script.

Las variables que no necesitan de información del usuario o una configuración previa se pueden crear en el lugar del script en el que se las necesita.

Si es necesario, puede asignar un valor en blanco a una variable de carácter o fechahora, de modo que la variable exista pero, inicialmente, esté vacía.

ASSIGN v_tabla_de_entrada = ""
ASSIGN v_lista_todos_campos = BLANKS(20000)
ASSIGN v_fecha_de_inicio = `19000101`

2.  Existen distintos métodos para crear una variable

La forma de crear una variable depende de cómo tiene pensado utilizarla.

nombre_variable = valor_variable

3.  El tipo de datos de una variable se especifica automáticamente

Al usar el comando ASSIGN, el tipo de datos del valor que se asigna a la variable dictamina el tipo de datos de la variable. Este proceso se conoce como "escritura implícita". En la mayoría de los casos, los tipos de datos de variables no se especifican explícitamente en Analytics.

Los tipos de valores que puede asignar a una variable

Puede asignar un valor literal a una variable o puede asignar un campo a una variable y la variable se inicializa con el valor del campo del registro actualmente seleccionado. También puede asignar el valor actual de una variable a otra variable.

Los tipos de datos de los valores

En Analytics, cada valor de datos es uno de los siguientes tipos (o categorías):

• Carácter

• Numérico

• Fechahora

• Lógico

El tipo de datos de un valor se establece de una de las siguientes maneras:

• Valor literal El tipo de datos de un valor literal se establece por la presencia o la ausencia de calificadores que encierren al valor y por los caracteres alfanuméricos que conforman el valor.

• Campo El tipo de datos de los valores de un campo se establecen por el tipo de datos del campo.

• Variable El tipo de datos de la variable "desde" y el valor que esta contiene ya está ajustado y se convierte en el tipo de datos de la variable "hasta". En general, una vez que cree una variable, no cambiará los tipos de datos; no obstante, nada impide que lo haga.

Ejemplos del uso del comando ASSIGN para crear variables de diferentes tipos de datos

ASSIGN v_tabla_de_entrada = "Número_de_proveedor"

ASSIGN v_identificador = Número_de_proveedor

ASSIGN v_cantidad_mín = 1000

ASSIGN v_total_acumulado = Importe_factura

ASSIGN v_fecha_de_inicio = `20210101`

ASSIGN v_fecha = Fecha_factura

ASSIGN v_T1 = T

ASSIGN v_aprobado = Aprobado

4.  Los nombres de las variables son flexibles y cuentan con algunas restricciones

En general, puede asignarle a la variable el nombre que mejor se adapte a su propósito.

Convenciones voluntarias

Las siguientes convenciones voluntarias hacen que sea más fácil leer y comprender los scripts:

• Asigne a las variables nombres descriptivos y fáciles de comprender que se relacionen de manera directa con el rol que desempeñan en un script. Es mejor tener un nombre un poco más extenso y claramente descriptivo que uno más breve y críptico que no permita comprender claramente el propósito de la variable.

• Adopte una convención general de asignación de nombres, como la de colocar una v_ antes del nombre de cada variable.

Restricciones impuestas

Analytics impone las siguientes restricciones a los nombres de las variables:

• Longitud máxima de 31 caracteres

• Caracteres válidos Caracteres alfanuméricos y carácter de guion bajo ( _ ). El nombre no puede contener ningún carácter especial ni espacios. Tampoco puede comenzar con un número.

  Nota

  No utilice caracteres no ingleses, como é , en los nombres de las variables que se utilizarán en la sustitución de variables. Los nombres de las variables con caracteres no ingleses impiden la correcta sustitución de la variable.

  Es posible que las versiones de este tema de Ayuda que no sean en inglés (por ejemplo, la versión en francés) muestren nombres de variables con caracteres acentuados. Asegúrese de que, en el script real, no haya ningún carácter acentuado en los nombres de las variables que se utilizarán para la sustitución de variables.

• Exclusividad Los nombres de las variables deben ser exclusivos dentro de un proyecto de Analytics porque las variables funcionan de manera global a lo largo de todo el proyecto

Los nombres de las variables no distinguen entre mayúsculas y minúsculas. En ACLScript, v_fecha_de_inicio y v_Fecha_de_Inicio son la misma variable.

5.  Una variable tiene un alcance global

Las variables creadas en un script de Analytics están disponibles para todas las partes subsiguientes del script. También están disponibles para cualquier otro script del proyecto de Analytics. Este comportamiento resulta útil si desea usar una variable en un script secundario que se define en un script principal.

ACLScript no admite el alcance local de las variables.

6.  Una variable continúa existiendo hasta que se cierra el proyecto de Analytics

Las variables permanecen en la memoria de su computadora hasta que se cierra el proyecto de Analytics que las contiene o hasta que se las elimina de manera explícita.

Si desea que una variable continúe existiendo después de cerrar un proyecto y que esté a su disposición cuando reabra el proyecto, puede crear una variable permanente. Para crear una variable permanente, coloque un guion bajo antes del nombre de la variable. Por ejemplo, _v_fecha_de_inicio. Tanto la variable como el valor que esta contiene continúan existiendo. La única forma de deshacerse de una variable permanente consiste en eliminarla de manera explícita.

7.  Las variables se pueden eliminar de forma explícita

Para eliminar explícitamente una o todas las variables de un proyecto de Analytics, use el comando DELETE en la línea de comandos o en un script.

Si desea eliminar una variable en particular:

DELETE nombre_variable OK

Si desea eliminar explícitamente todas las variables:

DELETE ALL OK

¿Qué se elimina?

Al eliminar una variable, usted está eliminando el contenedor con nombre y el valor que este contiene únicamente de la memoria de su computadora.

La eliminación de una variable no afecta nada relacionado con la variable en un script. Puede restaurar la variable en la memoria ejecutando manualmente el comando ASSIGN en la línea de comandos o ejecutando el script que contiene la asignación de la variable.

La eliminación de una variable y su valor no afecta nada de lo relacionado con el valor que exista por fuera de la variable, como una tabla de Analytics.

ASSIGN v_tabla_de_prueba = "Totales_acumulados"

COMMENT Se ejecuta correctamente
OPEN %v_tabla_de_prueba%

COMMENT Eliminar la variable
DELETE v_tabla_de_prueba OK

COMMENT Se ejecuta correctamente
OPEN Totales_acumulados

ASSIGN v_tabla_de_prueba = "Totales_acumulados"

COMMENT Se ejecuta correctamente
OPEN %v_tabla_de_prueba%

COMMENT Eliminar la tabla a la cual hace referencia la variable
DELETE FORMAT %v_tabla_de_prueba% OK

COMMENT Falla con el error "Tabla 'totales_acumulados' inválida"
OPEN %v_tabla_de_prueba%

8.  Las variables del sistema se crean automáticamente por medio de algunos comandos de Analytics.

Al ejecutar determinados comandos de Analytics, se crean automáticamente variables del sistema. Por ejemplo, el comando COUNT genera la variable del sistema COUNTn, que contiene la cantidad de registros que se contaron. Puede usar estas variables, y los valores que estas contienen, en partes posteriores de un script.

Por ejemplo, este script finaliza automáticamente si el usuario selecciona una tabla que no contiene registros:

ACCEPT "Seleccionar una tabla de entrada:" FIELDS "xf" TO v_tabla_de_entrada
OPEN %v_tabla_de_entrada%
COUNT
PAUSE "La tabla que seleccionó no contiene registros. Se finalizará el script." IF COUNT1 = 0
ESCAPE IF COUNT1 = 0
DO SCRIPT resumir_transacciones

Si desea obtener más información, consulte Las variables del sistema creadas por comandos de Analytics.

La importancia de los tipos de datos de una variable

Cuando una función o un comando de Analytics hace referencia a una variable, los tipos de datos de la variable deben coincidir con el tipo de datos aceptado por el comando o la función. Si los tipos de datos no coinciden, obtendrá un error y el procesamiento del comando o de la función no se podrá completar correctamente.

Para evitar un error en estas situaciones, puede usar funciones de Analytics para convertir el valor almacenado de una variable en un tipo de datos que se pueda utilizar. Por ejemplo, esta expresión convierte una fecha almacenada en una variable de caracteres en el tipo de datos de fechahora:

CTOD(v_fecha_en_caracteres)

Esta expresión convierte un número almacenado en una variable de caracteres en datos de tipo numérico:

VALUE(v_número_en_caracteres; 2)

Si desea obtener más información, consulte Funciones de conversión.

Algunas palabras sobre los valores de fechahora

En Analytics, puede procesar valores de fechahora que utilizan tanto el tipo de datos de fechahora como el tipo de datos de carácter. En general, los tipos de datos asociados con los valores de fechahora se basan en la naturaleza de los datos al importarlos a Analytics.

¿Cuál es la implicancia para las variables que contienen valores de fecha, hora o fechahora? Para simplificar, debe conocer el tipo de datos de los datos subyacentes con los que está trabajando. La sintaxis del script debe ser diferente según el tipo de datos que se utilice.'

SET FILTER TO BETWEEN(campo_fecha_fechahora; CTOD(v_fecha_de_inicio); CTOD(v_fecha_de_finalización))

SET FILTER TO BETWEEN(campo_de_fecha_carácter; v_fecha_de_inicio; v_fecha_de_finalización)

Sustitución de variables

Al utilizar una variable de caracteres como entrada para un comando o una función de Analytics, debe reemplazar el nombre de la variable por el valor de la variable. Si no realiza esta sustitución, el comando o la función intenta operar en el nombre de la variable en lugar de hacerlo con el valor que esta contiene y obtendrá un error.

La sustitución de variables es un método para reemplazar el nombre de la variable por el valor que contiene la variable de caracteres. Para utilizar la sustitución de variables, debe encerrar el nombre de la variable de caracteres entre signos de porcentaje ( % ). Por ejemplo, %v_tabla_de_entrada% recupera el nombre de la tabla real almacenado en v_tabla_de_entrada y lo utiliza para reemplazar el nombre de la variable.

Como la entrada de un usuario para un script suele estar almacenada en una variable de caracteres, un uso común de la sustitución se da al incorporar las entradas de los usuarios en la lógica del script.

ACCEPT "Seleccionar una tabla de entrada:" FIELDS "xf" TO v_tabla_de_entrada
OPEN %v_tabla_de_entrada%

ACCEPT "Seleccionar una tabla de entrada:" FIELDS "xf" TO v_tabla_de_entrada
OPEN v_tabla_de_entrada

El uso de la sustitución de variables puede ser complejo

En determinadas situaciones podría parecer que es necesario utilizar la sustitución de variables, pero su uso causa un error.

Consideremos uno de los ejemplos que presentamos antes:

SET FILTER TO BETWEEN(campo_de_fecha_carácter; v_fecha_de_inicio; v_fecha_de_finalización)

En este ejemplo, está comparando valores de fecha almacenados como datos de caracteres tanto en las variables como en el campo. Por eso, el uso de la sustitución de variables debería funcionar correctamente:

SET FILTER TO BETWEEN(campo_de_fecha_carácter; %v_fecha_de_inicio%; %v_fecha_de_finalización%)

Pero, ¿por qué la sustitución de variables causa un error en esta situación? La respuesta es que la sustitución de variables es absolutamente literal. Para solucionar el error, mire los valores exactos almacenados en las variables, reemplácelos manualmente en la expresión y observe la expresión que se obtiene. Por ejemplo:

SET FILTER TO BETWEEN(campo_de_fecha_carácter; 20000101; 20001231)

Esta expresión compara fechas que utilizan un tipo de datos de carácter con números que, después de la sustitución, utilizan un tipo de datos numérico. Esto provoca una falta de coincidencia entre los tipos de datos.

Como especificó un campo de caracteres con BETWEEN( ), la función interpreta automáticamente los valores de v_fecha_de_inicio y v_fecha_de_finalización como valores de caracteres y no es necesario utilizar la sustitución de variables.

Si desea obtener más información, consulte Resolución de problemas.

Una excepción a la regla

En algunos casos, tal vez pueda usar la sustitución de variables con una variable numérica sin que haya ningún problema. La ventaja es que el valor de la variable numérica se captura en el registro, lo cual puede ser útil para la solución de problemas.

Los dos ejemplos que se incluyen a continuación asignan el valor de la variable numérica COUNT1 a la variable numérica v_recuento. Sin embargo, en el primer ejemplo, el valor asignado real no se captura en el registro. En el segundo ejemplo, se captura el valor real.

COMMENT entrada de registro: ASSIGN v_recuento = COUNT1
ASSIGN v_recuento = COUNT1

COMMENT entrada de registro: ASSIGN v_recuento = 500
ASSIGN v_recuento = %COUNT1%

Mantenimiento manual de las variables

Puede mantener variables manualmente utilizando el cuadro de diálogo Variables, disponible desde el menú principal de Analytics. Puede crear, renombrar, duplicar o eliminar variables, o actualizar los valores de las variables.

El mantenimiento que realice solo afecta la instancia actual de la variable en la memoria. Por ejemplo, si renombra una variable, está renombrando únicamente la instancia de la variable en la memoria. No está renombrando la variable en un script.

1. Desde el menú principal de Analytics, seleccione Editar > Variables.

   Se abre el cuadro de diálogo Variables y muestra una lista de todas las variables del sistema y las definidas por el usuario en el proyecto. Las variables se crean automáticamente por medio de comandos.

2. Complete cualquiera de las siguientes acciones:

   Crear una nueva variable	Haga clic en Nuevo para abrir el Generador de expresiones. En el cuadro de texto Expresión, introduzca la expresión o el valor que se asignará a la variable. Los valores literales deben utilizar el formato y los calificadores adecuados (cuando sea necesario). Si desea obtener más información, consulte El tipo de datos de una variable se especifica automáticamente. Opcional. Haga clic en Verificar para comprobar que el valor o la expresión sean válidos. Escriba el nombre de la variable en el cuadro de texto Guardar como. Si desea obtener más información, consulte: Los nombres de las variables son flexibles y cuentan con algunas restricciones Las variables continúan existiendo hasta que se cierra el proyecto de Analytics Haga clic en Aceptar. Se crea la variable y esta aparece en la ficha Variables.
   Actualizar el valor de una variable	Seleccione una variable de la lista y haga clic en Aceptar para abrir el Generador de expresiones. En el cuadro de texto Expresión, actualice el valor o la expresión que se asignó a la variable. Los valores literales deben utilizar el formato y los calificadores adecuados (cuando sea necesario). Si desea obtener más información, consulte El tipo de datos de una variable se especifica automáticamente. Opcional. Haga clic en Verificar para comprobar que el valor o la expresión sean válidos. Haga clic en Aceptar. El valor asignado a la variable se actualiza en la memoria de la computadora.
   Renombrar una variable	Seleccione una variable de la lista y haga clic en Renombrar. En el cuadro de texto Renombrar, escriba un nuevo nombre y haga clic en Aceptar. El valor asignado a la variable se actualiza en la memoria de la computadora. Haga clic en Cancelar para cerrar el cuadro de diálogo Variables.
   Duplicar una variable	Seleccione una variable de la lista y haga clic en Duplicar. La variable y su valor se duplican en la memoria de su computadora. Se agrega un sufijo numérico al nombre de la variable duplicada. Realice una de las siguientes acciones: Haga clic en Terminado para cerrar el cuadro de diálogo Variables. Haga clic en Aceptar para actualizar el valor o la expresión que se asignó a la variable.
   Eliminar una variable	Seleccione una variable de la lista. Opcional. Utilice Mayús+clic o Ctrl+clic para seleccionar varias variables para eliminarlas. Haga clic en Eliminar. Haga clic nuevamente en Eliminar. La o las variables se eliminan de la memoria de su computadora. Haga clic en Terminado para cerrar el cuadro de diálogo Variables.

Ejemplos de uso de una variable

• Variables para la configuración del script

• Variables para la información de entrada del usuario

• Los valores predeterminados para las variables de entrada del usuario

• Variables para almacenamiento temporal

COMMENT Crear e inicializar variables para tasas de impuesto a las ventas y un rango de fechas
COMMENT De ser necesario, puede extender el script agregando más variables de tasas de impuestos y rangos de fechas
ASSIGN v_impuesto_1 = 0,05
ASSIGN v_impuesto_2 = 0,06
ASSIGN v_impuesto_2_inicio = `20210701`
ASSIGN v_impuesto_2_finalización = `20211231`

COMMENT Crear un campo calculado condicional que utiliza las tarifas del impuesto a las ventas para dos períodos diferentes
DEFINE FIELD impuesto_ventas COMPUTED

Importe_factura * v_impuesto_2 IF BETWEEN(Importe_factura; v_impuesto_2_inicio; v_impuesto_2_finalización)
Importe_factura * v_impuesto_1

OPEN %v_tabla_de_entrada%

COMMENT Crear un cuadro de diálogo para solicitarle al usuario una tabla de entrada y una tabla de salida
ACCEPT "Seleccionar una tabla de entrada:" FIELDS "xf" TO v_tabla_de_entrada; "Especificar un nombre de tabla de entrada (sin espacios):" TO v_tabla_de_salida

COMMENT Abrir la tabla de entrada seleccionada por el usuario
OPEN %v_tabla_de_entrada%

COMMENT Crear un cuadro de diálogo para solicitar al usuario un campo numérico y un rango numérico
ACCEPT "Seleccionar un campo numérico para filtrar:" FIELDS "N" TO v_campo_numérico; "Especificar una cantidad mínima:" TO v_cantidad_mín; "Especificar una cantidad máxima:" TO v_cantidad_máx

COMMENT Crear un cuadro de diálogo para solicitar al usuario un campo de fecha y un rango de fechas
ACCEPT "Seleccionar un campo de fecha para filtrar:" FIELDS "D" TO v_campo_de_fecha; "Especifique una fecha de inicio (YYYYMMDD):" TO v_fecha_de_inicio; "Especifique una fecha de finalización (YYYYMMDD):" TO v_fecha_de_finalización

COMMENT Filtrar la tabla de entrada según los rangos numéricos y de fecha del usuario
SET FILTER TO BETWEEN(%v_campo_numérico%; VALUE(v_cantidad_mín; 2); VALUE(v_cantidad_máx; 2)) AND BETWEEN(%v_campo_de_fecha%; CTOD(v_fecha_de_inicio); CTOD(v_fecha_de_finalización))

COMMENT Extraer el conjunto de registros filtrados a la tabla de salida especificada por el usuario
EXTRACT RECORD TO %v_tabla_de_salida%

COMMENT Abrir la tabla de salida con los registros filtrados
OPEN %v_tabla_de_salida%

COMMENT Establecer el formato de fecha para la duración de la sesión de Analytics
SET DATE "YYYYMMDD"

COMMENT Especificar los valores predeterminados para los extremos inferior y superior del rango numérico
ASSIGN v_cantidad_mín = STRING(5000; 4)
ASSIGN v_cantidad_máx = STRING(100000; 6)

COMMENT Especificar la duración del rango de fechas calculado en meses
ASSIGN v_cantidad_de_meses = 12

COMMENT Calcular las fechas de inicio y finalización del rango de fechas predeterminado en la fecha actual y la duración especificada por v_cantidad_de_meses
ASSIGN v_fecha_de_finalización = ALLTRIM(DATE(EOMONTH(TODAY();-1)))
ASSIGN v_fecha_de_inicio = ALLTRIM(DATE(EOMONTH(CTOD(v_fecha_de_finalización); -v_cantidad_de_meses) + 1))

COMMENT Crear un cuadro de diálogo para solicitarle al usuario una tabla de entrada y una tabla de salida
ACCEPT "Seleccionar una tabla de entrada:" FIELDS "xf" TO v_tabla_de_entrada; "Especificar un nombre de tabla de entrada (sin espacios):" TO v_tabla_de_salida

COMMENT Abrir la tabla de entrada seleccionada por el usuario
OPEN %v_tabla_de_entrada%

COMMENT Crear un cuadro de diálogo para solicitar al usuario un campo numérico y un rango numérico
ACCEPT "Seleccionar un campo numérico para filtrar:" FIELDS "N" TO v_campo_numérico; "Especificar una cantidad mínima:" TO v_cantidad_mín; "Especificar una cantidad máxima:" TO v_cantidad_máx

COMMENT Crear un cuadro de diálogo para solicitar al usuario un campo de fecha y un rango de fechas
ACCEPT "Seleccionar un campo de fecha para filtrar:" FIELDS "D" TO v_campo_de_fecha; "Especifique una fecha de inicio (YYYYMMDD):" TO v_fecha_de_inicio; "Especifique una fecha de finalización (YYYYMMDD):" TO v_fecha_de_finalización

COMMENT Filtrar la tabla de entrada según los rangos numéricos y de fecha del usuario
SET FILTER TO BETWEEN(%v_campo_numérico%; VALUE(v_cantidad_mín; 2); VALUE(v_cantidad_máx; 2)) AND BETWEEN(%v_campo_de_fecha%; CTOD(v_fecha_de_inicio); CTOD(v_fecha_de_finalización))

COMMENT Extraer el conjunto de registros filtrados a la tabla de salida especificada por el usuario
EXTRACT RECORD TO %v_tabla_de_salida%

COMMENT Abrir la tabla de salida con los registros filtrados
OPEN %v_tabla_de_salida%

COMMENT
Permitir la sobrescritura de archivos sin mostrar un cuadro de diálogo de confirmación
END
SET SAFETY OFF

COMMENT
Crear un cuadro de diálogo para solicitarle al usuario una tabla de entrada y una tabla de salida
END
ACCEPT "Seleccionar una tabla de entrada:" FIELDS "xf" TO v_tabla_de_entrada; "Especificar un nombre de tabla de entrada (sin espacios):" TO v_tabla_de_salida
OPEN %v_tabla_de_entrada%

COMMENT
Crear un cuadro de diálogo para solicitarle al usuario un campo de identificador de caracteres
END
ACCEPT "Seleccionar un campo de identificador de caracteres:" FIELDS "C" TO v_campo_de_id

COMMENT
Crear un cuadro de diálogo para solicitar al usuario un campo numérico
END
ACCEPT "Seleccionar un campo numérico:" FIELDS "N" TO v_campo_numérico

COMMENT
Indexar (ordenar) la tabla por el campo de identificador de caracteres
END
INDEX ON %v_campo_de_id% TO "campo_de_ID_ordenado"
SET INDEX TO "campo_de_ID_ordenado"

COMMENT
Asignar el valor actual del campo de identificador de caracteres a la variable v_valor_de_id.
Cuando se abre la v_tabla_de_entrada por primera vez, el valor actual es el primer valor del campo. De allí en adelante, el valor real depende del registro que está procesando el script.
END
ASSIGN v_valor_de_id = %v_campo_de_id%

COMMENT
Establecer el valor de inicio para el total acumulado en cero (0,00)
END
ASSIGN v_total_acumulado = 0,00

COMMENT
Procesar la tabla registro por registro. Para cada identificador exclusivo, calcular un total acumulado para el campo numérico.
END
GROUP IF v_valor_de_id = %v_campo_de_id%
  ASSIGN  v_total_acumulado = v_total_acumulado + %v_campo_numérico%
  EXTRACT %v_campo_de_id% %v_campo_numérico% v_total_acumulado AS "%v_campo_numérico% total_acumulado" TO %v_tabla_de_salida%
ELSE
  ASSIGN v_valor_de_id = %v_campo_de_id%
  ASSIGN v_total_acumulado = 0,00
  ASSIGN  v_total_acumulado = v_total_acumulado + %v_campo_numérico%
  EXTRACT %v_campo_de_id% %v_campo_numérico% v_total_acumulado AS "%v_campo_numérico% total_acumulado" TO %v_tabla_de_salida%
END

COMMENT Abrir la tabla de salida con los totales acumulados calculados
OPEN %v_tabla_de_salida%

COMMENT Restaurar el comportamiento predeterminado de mostrar un cuadro de diálogo de confirmación antes de sobrescribir los archivos
SET SAFETY ON

Resolución de problemas

Al trabajar con variables en los scripts, hay dos categorías generales de error que se presentan con más frecuencia:

• Resultados inesperados El script se ejecuta por completo, pero el análisis que incluye variables no genera los resultados esperados.

• Problema con el tipo de datos El script no se logra completar y genera un error relacionado con el tipo de datos, como "Falta de coincidencia del tipo de expresión" o "Se requiere una expresión de carácter".

Resultados inesperados

Para el primer tipo de error, pruebe el siguiente enfoque de solución:

1. En el Navegador, abra la ficha Variables.

2. En la línea de comandos de Analytics escriba DELETE ALL OK para eliminar las variables existentes.

   Si el cuadro de texto Línea de comandos no está visible, seleccione Ventana > Línea de comandos.

3. En el Editor de scripts, utilice la opción Paso para recorrer el script línea por línea y hacer un seguimiento de la creación de cada variable y valor asignado en la ficha Variables.

   Es posible que descubra que el valor que se asignó a una variable no sea el que usted deseaba y deberá ajustar la lógica del script. Si desea obtener más información, consulte Prueba y depuración de scripts.

Problema con el tipo de datos

Al desarrollar scripts que utilizan variables, es posible que se enfrente a errores causados por la falta de correspondencia en los tipos de datos. Es muy probable que surjan errores si está combinando funciones de conversión y sustitución de variables en la misma expresión.

Es normal encontrar errores y la manera de subsanarlos es probar diferentes enfoques y tener en cuenta los siguientes principios:

• Prestar mucha atención a los tipos de datos en cada elemento de una expresión. ¿Los tipos de datos de la expresión coinciden con lo que requiere ACLScript?

• Recordar que la sustitución de variables es absolutamente literal. Si cree que la sustitución de variables está causando el error, busque el valor exacto almacenado en una variable y reemplace manualmente el valor en la expresión. Realizar este simple diagnóstico de errores puede revelar cuál es el problema.

• La inserción del comando DISPLAY VARIABLES en diferentes lugares de un script le permite capturar el estado de las variables del proyecto en un momento determinado.

• Recorrer un script línea por línea y establecer puntos de quiebre puede facilitar mucho el diagnóstico de errores. Si desea obtener más información, consulte Prueba y depuración de scripts.