Les exemples de scripts d'outils d'analyse contiennent un script d'importation, un script de préparation et un script d'analyse. Les scripts d'analyse peuvent être exécutés dans Robots.
Ordre d'exécution des scripts d'outils d'analyse
Les trois scripts d'outils d'analyse sont destinés à être utilisés conjointement et doivent être exécutés dans l'ordre suivant :
| Séquence | ANALYTIC TYPE | Nom du script d'outil d'analyse |
|---|---|---|
| 1 | IMPORT |
Exemple d'importation d'outil d'analyse Robots_AX |
| 2 | PREPARE | Exemple d'outil d'analyse de préparation |
| 3 | ANALYSIS | Exemple d'outil d'analyse d'analyse |
Exemple de script d'outil d'analyse d'importation
Importe des données de l'exemple de fichier Excel Trans_Mai.xls et les enregistre dans la nouvelle table Analytics Trans_Mai_brute (la table de données brute).
| Nom du script d'outil d'analyse | À utiliser dans | Condition requise pour le fichier d'importation |
|---|---|---|
| Exemple d'importation d'outil d'analyse Robots_AX |
|
|
Exemple du script d'outil d'analyse d'importation à utiliser dans Robots
COMMENT
//ANALYTIC TYPE IMPORT Exemple d'outil d'analyse d'importation Robots_AX
Ce script d'outil d'analyse importe des données de l'exemple de fichier Excel Trans_Mai.xls et les enregistre dans la nouvelle table Analytics "Trans_Mai_brute" (la table de données brute).
//FILE Trans_Mai.xls
//DATA Trans_Mai_brut
//RESULT LOG
END
SET SAFETY OFF
IMPORT EXCEL TO Trans_Mai_brut Trans_Mai_brut.fil FROM "Trans_Mai.xls" TABLE "Trans2_Mai$" KEEPTITLE FIELD "NUMCARTE" C WID 22 AS "" FIELD "CODES" C WID 4 AS "" FIELD "DATE" D WID 10 PIC "AAAA-MM-JJ" AS "" FIELD "NUMCLIENT" C WID 6 AS "" FIELD "DESCRIPTION" C WID 95 AS "" FIELD "MONTANT" N WID 9 DEC 2 AS ""
SET SAFETY ON
Exemple de script d'outil d'analyse de préparation
Prépare la table de données brute pour l'analyse et l'enregistre dans la nouvelle table Analytics Trans_Mai_préparée (la table d'analyse). Le script d'outil d'analyse définit une version plus courte du champ « Description », car le classement prend uniquement en charge des longueurs de champ de 64 caractères au maximum.
COMMENT
//ANALYTIC TYPE PREPARE Exemple d'outil d'analyse de préparation
Ce script d'outil d'analyse prépare la table de données brute pour l'analyse et l'enregistre dans la nouvelle table Analytics "Trans_Mai_préparée" (la table d'analyse). Le script d'outil d'analyse définit une version plus courte du champ « Description », car le classement prend uniquement en charge des longueurs de champ de 64 caractères au maximum.
//TABLE v_TableBrute Table à préparer
Sélectionnez la table de données brutes que vous souhaitez préparer
//RESULT TABLE Trans_*_préparée
//DATA Trans_*_préparée
//RESULT LOG
END
SET SAFETY OFF
OPEN %v_TableBrute%
DEFINE FIELD DESC_SHORT ASCII 43 64
EXTRACT RECORD TO "Trans_Mai_préparée"
SET SAFETY ON
Exemples de script d'outil d'analyse d'analyse
Classe la table d'analyse et sort les résultats dans une nouvelle table Analytics Classée_Trans_Mai_préparée (la table de résultats). Les utilisateurs peuvent spécifier le champ à utiliser pour classer la table ainsi que les codes de catégories de marchands, les numéros de clients, les périodes et les plages des montants de transactions pour limiter le nombre d'enregistrements à traiter.
COMMENT
//ANALYTIC TYPE ANALYSIS Exemple d'outil d'analyse d'analyse
Ce script d'outil d'analyse classe la table d'analyse et sort les résultats dans une nouvelle table Analytics « Classée_Trans_Mai_préparée » (la table de résultats). Vous pouvez spécifier les codes de catégories de marchands, les numéros de clients, les périodes et les plages des montants de transactions pour limiter le nombre d'enregistrements à traiter.
//TABLE v_TableAnalyse Table à classer
Sélectionnez la table d'analyse que vous souhaitez classer
//FIELD v_ChampA C Champ par rapport auquel classer
Sélectionner le champ selon lequel classer
//PARAM v_codes C MULTI SEPARATOR , QUALIFIER ' VALUES |4112 Transport ferroviaire de passagers|4121 Taxis/Limousines|4131 Voyage en autobus|4215 Services de coursier - Air ou sol|4411 Croisières|4457 Locations de bateau|4722 Agences de voyages et tour-opérateurs|4814 Appels locaux/longue distance|5812 Restaurants|5813 Cafés (boissons alcoolisées)|5814 Fast foods|5921 Détaillants d'alcool, bière, vin, liqueur|5993 Marchands de cigares et comptoirs à tabac|5994 Buraliste|7216 Nettoyage à sec| MC Code(s) à inclure
Spécifiez un ou plusieurs codes de catégories de marchands à inclure
//PARAM v_num_client C OPTIONAL MULTI SEPARATOR , QUALIFIER ' Numéros clients à exclure (facultatif)
Spécifiez un ou plusieurs numéros clients à exclure Appuyez sur « Entrée » après chaque numéro pour que chaque numéro se trouve sur une ligne distincte. N'entourez pas les numéros de guillemets.
//PARAM v_start_date D VALUES |05/01/2003|05/02/2003|05/03/2003|05/04/2003|05/05/2003|05/06/2003|05/07/2003|05/08/2003|05/09/2003|05/10/2003|05/11/2003|05/12/2003|05/13/2003|05/14/2003|05/15/2003|05/16/2003|05/17/2003|05/18/2003|05/19/2003|05/20/2003|05/21/2003|05/22/2003|05/23/2003|05/24/2003|05/25/2003|05/26/2003|05/27/2003|05/28/2003|05/29/2003|05/30/2003|05/31/2003|Date de début
Sélectionnez une date de début
//PARAM v_date_fin D Date de fin
Saisissez une date de fin ou sélectionnez-en une dans le calendrier
//PARAM v_montant_min N Montant minimum
Saisissez un montant minimum
//PARAM v_montant_max N Montant maximum
Saisissez un montant maximum
//RESULT TABLE Classée_*
//RESULT LOG
END
SET SAFETY OFF
OPEN %v_TableAnalyse%
IF NOT ISDEFINED("v_num_client") v_num_client = ""
GROUP IF v_num_client = ""
CLASSIFY ON %v_ChampA% IF MATCH(CODES; %v_codes%) AND BETWEEN(DATE; v_date_début; v_date_fin) AND BETWEEN(MONTANT; v_montant_min; v_montant_max)SUBTOTAL MONTANT TO "Classée_%v_TableAnalyse%.FIL" OPEN
ELSE
CLASSIFY ON %v_ChampA% IF MATCH(CODES; %v_codes%) AND NOT MATCH(NUMCLIENT; %v_num_client%) AND BETWEEN(DATE; v_date_début; v_date_fin) AND BETWEEN(MONTANT; v_montant_min; v_montant_max) SUBTOTAL MONTANT TO "Classée_%v_TableAnalyse%.FIL" OPEN
END
SET SAFETY ON
