Los scripts de estudios analíticos de ejemplo contienen un script de importación, un script de preparación y un script de análisis. Los scripts de estudios analíticos se pueden ejecutar en Robots.

Los tres scripts de estudios analíticos están diseñados para funcionar juntos y se los debe ejecutar en la siguiente secuencia:

Secuencia ANALYTIC TYPE Nombre del script del estudio analítico
1 IMPORT

Estudio analítico de importación de ejemplo Robots_AX

2 PREPARE Estudio analítico de preparación de ejemplo
3 ANALYSIS Estudio analítico de análisis de ejemplo

Importa datos desde un archivo Excel de ejemplo "Trans_Mayo.xls" y los guarda en la nueva tabla de Analytics Trans_Mayo_sin_procesar (la tabla de datos sin procesar).Analytics

Nombre del script del estudio analítico Utilizar en Requisito del archivo de importación
Estudio analítico de importación de ejemplo Robots_AX
  • Robots
  • Robots Trans_Mayo.xls debe estar ubicado en la ficha Entrada/Salida del mismo robot que el script de estudio analítico

Script de estudio analítico de importación de ejemplo para su uso en Robots

COMMENT
//ANALYTIC TYPE IMPORT Estudio analítico de importación de ejemplo Robots_AX
  Este script de estudio analítico importa datos desde el archivo Excel de ejemplo Trans_Mayo.xls y los guarda en la nueva tabla de Analytics "Trans_Mayo_sin_procesar" (la tabla de datos sin procesar).
//FILE Trans_Mayo.xls
//DATA Trans_Mayo_sin_procesar
//RESULT LOG
END

SET SAFETY OFF
IMPORT EXCEL TO Trans_Mayo_sin_procesar Trans_Mayo_sin_procesar.fil FROM "Trans_Mayo.xls" TABLE "Trans2_Mayo$" KEEPTITLE FIELD "CARDNUM" C WID 22 AS "" FIELD "CODES" C WID 4 AS "" FIELD "DATE" D WID 10 PIC "AAAA-MM-DD" AS "" FIELD "CUSTNO" C WID 6 AS "" FIELD "DESCRIPTION" C WID 95 AS "" FIELD "AMOUNT" N WID 9 DEC 2 AS ""
SET SAFETY ON

Prepara la tabla de datos sin procesar para el análisis y la guarda en la nueva tabla de Analytics Trans_Mayo_preparada (la tabla de análisis). El script de estudio analítico define una versión más corta del campo “Descripción” porque la clasificación únicamente admite longitudes de campo de hasta 64 caracteres.

COMMENT
//ANALYTIC TYPE PREPARE Estudio analítico de preparación de ejemplo
  Este script de estudio analítico prepara la tabla de datos sin procesar para el análisis y la guarda en la nueva tabla de Analytics "Trans_Mayo_preparada" (la tabla de análisis). El script de estudio analítico define una versión más corta del campo “Descripción” porque la clasificación únicamente admite longitudes de campo de hasta 64 caracteres.
//TABLE v_Tabla_sin_procesar Tabla que se debe preparar
  Seleccione la tabla de datos sin procesar que desea preparar
//RESULT TABLE Trans_*_preparada
//DATA Trans_*_preparada
//RESULT LOG
END

SET SAFETY OFF
OPEN %v_Tabla_sin_procesar%
DEFINE FIELD DESC_SHORT     ASCII      43  64
EXTRACT RECORD TO "Trans_Mayo_preparada"
SET SAFETY ON

Clasifica la tabla de análisis y envía los resultados a la nueva tabla de Analytics Trans_Mayo_preparada_clasificada (la tabla de resultados). Los usuarios pueden especificar qué campo utilizar para clasificar la tabla y pueden especificar los códigos de categoría de comerciante, los números de cliente y los intervalos de fecha y de importe de las transacciones para restringir los registros que se procesan.

COMMENT
//ANALYTIC TYPE ANALYSIS Estudio analítico de análisis de ejemplo
  Este estudio analítico clasifica la tabla de análisis y envía los resultados a la nueva tabla de Analytics “Trans_Mayo_preparada_clasificada” (la tabla de resultados). Puede especificar códigos de categoría de comerciante, números de cliente e intervalos de fecha y de importe de las transacciones para restringir los registros que se procesan.
//TABLE v_TablaAnálisis Tabla que se debe clasificar
  Seleccione la tabla de análisis que desea clasificar
  //FIELD v_CampoA C Campo que se debe utilizar para clasificar
  Seleccione el campo en base al cual desea clasificar
//PARAM v_códigos C MULTI SEPARATOR , QUALIFIER ' VALUES |4112 Ferrocarriles de pasajeros|4121 Taxis/Limusinas|4131 Autobús|4215 Servicios de courier - Aéreo o Terrestre|4411 Líneas de cruceros|4457 Alquiler de embarcaciones|4722 Agencias de viajes y operadores de turismo|4814 Llamadas locales/larga distancia|5812 Restaurantes|5813 Bares (Bebidas alcohólicas)|5814 Restaurantes de comida rápida|5921 Cerveza, vino, licor|5993 Cigarrerías|5994 Puestos de diarios|7216 Tintorerías| MC Código de comerciante para incluir 
  Especifique uno o más códigos de categoría de comerciante para incluir
//PARAM v_núm_cliente C OPTIONAL MULTI SEPARATOR , QUALIFIER ' Números de cliente para excluir (opcional)
  Especifique uno o más números de cliente para excluir. Pulse "Intro" después de cada número, para que cada número quede en una línea separada. No encierre los números entre comillas.
//PARAM v_start_date D VALUES |05/01/2003|05/02/2003|05/03/2003|05/04/2003|05/05/2003|05/06/2003|05/07/2003|05/08/2003|05/09/2003|05/10/2003|05/11/2003|05/12/2003|05/13/2003|05/14/2003|05/15/2003|05/16/2003|05/17/2003|05/18/2003|05/19/2003|05/20/2003|05/21/2003|05/22/2003|05/23/2003|05/24/2003|05/25/2003|05/26/2003|05/27/2003|05/28/2003|05/29/2003|05/30/2003|05/31/2003|Fecha de inicio
  Seleccione una fecha de inicio
//PARAM v_fecha_de_finalización D Fecha de finalización
  Escriba una fecha de finalización o escoja una del calendario
//PARAM v_importe_mín N Importe mínimo
  Introduzca un importe mínimo
//PARAM v_importe_máx N Importe máximo
  Introduzca un importe máximo
//RESULT TABLE *_clasificada
//RESULT LOG
END

SET SAFETY OFF
OPEN %v_TablaAnálisis%
IF NOT ISDEFINED("v_núm_cliente") v_núm_cliente = ""
GROUP IF v_núm_cliente = ""
  CLASSIFY ON %v_CampoA% IF MATCH(CODES; %v_códigos%) AND BETWEEN(DATE; v_fecha_de_inicio; v_fecha_de_finalización) AND BETWEEN(AMOUNT; v_importe_mín; v_importe_máx) SUBTOTAL AMOUNT TO "%v_TablaAnálisis%_clasificada.FIL" OPEN
ELSE
  CLASSIFY ON %v_CampoA% IF MATCH(CODES; %v_códigos%) AND NOT MATCH(CUSTNO; %v_núm_cliente%) AND BETWEEN(DATE; v_fecha_de_inicio; v_fecha_de_finalización) AND BETWEEN(AMOUNT; v_importe_mín; v_importe_máx) SUBTOTAL AMOUNT TO "%v_TablaAnálisis%_clasificada.FIL" OPEN
END
SET SAFETY ON