Alles zusammen: Funktionen in einem Skript nutzen

Im abschließenden Tutorial für Analytics-Funktionen fassen wir alles zusammen, indem wir Variablen mit einer Reihe von Funktionen in einem Skript verwenden, das eine praxisbezogene Aufgabe durchführt.

Hinweis

Sie müssen keine Skripting-Kenntnisse aufweisen, um dieses Tutorial zu verstehen. Das vorgefertigte Skript kopieren Sie und fügen es am Ende des Tutorials in Analytics ein.

Was das Skript tut

Das Beispielskript ermöglicht jeder Person, die das Skript ausführt, einen Datumsfilter auf eine beliebige Analytics-Tabelle mit einem Datumsfeld anzuwenden und die durch den Filter berücksichtigten Datensätze dann nach Monaten zu gruppieren.

Das Skript kombiniert Operationen, die bereits in früheren Funktionstutorials erläutert wurden.

Bedeutung von Funktionen in einem Skript

Innerhalb eines einzelnen Skripts nutzt ein Analytics-Skriptautor unter Umständen zahlreiche Funktionen, um unterschiedliche kleine, jedoch bedeutende Hilfsaufgaben durchzuführen, die zu der gesamten Datenanalyse des Skripts beitragen.

Wenn eine Funktion in ein Skript eingefügt wird, ändert sich dadurch nichts an der Funktionsweise der Funktion. Funktionen laufen in Skripts ganz genauso ab, wie sie sich bei einer isolierten Nutzung in der Analytics-Befehlszeile verhalten.

Empfohlene Übungen

  • Das Skript anschauen

    Sehen Sie sich das Beispielskript unten im Tutorial an. Analytics-Skripts werden sequenziell, Zeile für Zeile ausgeführt. Sie können also ein Skript sequenziell durchlaufen und jeden Kommentar (COMMENT) lesen, um eine allgemeine Vorstellung zu erhalten, wie das Skript funktioniert.

    COMMENT-Zeilen sind kein Bestandteil der Skriptlogik und werden daher nicht ausgeführt.

  • Aufgabe von Funktionen verstehen

    Achten Sie besonders auf die Funktionen innerhalb des Skripts. Sie sind braun hervorgehoben. Beachten Sie die Tabelle über dem Skript, die zusätzliche Einzelheiten über die kleine Aufgabe jeder Funktion enthält.

    Wenn Sie die vorherigen Funktionstutorials absolviert haben, werden Ihnen die meisten Funktionen innerhalb des Skripts und deren Aufgaben bereits bekannt erscheinen.

  • Das Skript ausführen

    Sobald Sie sich mit dem Skript und den in ihm enthaltenen Funktionen vertraut gemacht haben, kopieren Sie das Skript und fügen es in Analytics ein. Führen Sie es dann aus, um zu sehen, wie Sie mit ihm interagieren können.

Wie das Beispielskript in Analytics ausgeführt wird

  1. Öffnen Sie ein Analytics-Projekt, das ein oder mehrere Tabellen mit Datumsfeldern enthält.

    Beispielprojekt.ACL weist mehrere Tabellen mit Datumsfeldern auf.

  2. Erstellen Sie ein neues, leeres Skript:
    1. Klicken Sie im Navigator mit der rechten Maustaste auf einen Ordner oder den Projekteintrag auf oberster Ebene, und wählen Sie Neu > Skript.
    2. Kopieren Sie das gesamte folgende Skript und fügen Sie es im Skript-Editor in das neue Skript ein.
    3. Speichern Sie das Projekt.
  3. Klicken Sie auf Ausführen , um das Skript auszuführen.
  4. Folgen Sie den Eingabeaufforderungen im Dialogfeld, um eine Tabelle und ein Datumsfeld auszuwählen. Geben Sie das Start- und Enddatum an, und wählen Sie ein numerisches Zwischensummenfeld aus.

Beispielskript: Datensätze filtern und gruppieren

Das Beispielskript erledigt zwei Hauptaufgaben:

  • Es filtert die Datensätze in einer Tabelle nach dem Datum und verwendet hierbei die von Ihnen festgelegten Datumswerte.
  • Es gruppiert die durch den Filter ausgewählten Datensätze nach Monaten.

Sie müssen sich keine Sorgen machen, falls Sie nicht die gesamte Skriptsyntax verstehen. Wir möchten hauptsächlich die unterschiedlichen Analytics-Funktionen innerhalb eines Skripts in Aktion zeigen.

Ein Kommentar (COMMENT) vor jedem Abschnitt mit Skriptsyntax erläutert in einfachen Worten, was die Syntax tut.

Im Beispielskript verwendete Funktionen

Der Zweck jeder innerhalb des Beispielskripts verwendeten Funktion wird im Folgenden beschrieben.

Die Funktionen sind innerhalb des Skripts braun hervorgehoben.

Funktionen innerhalb des Skripts Zweck
DATE( )

Konvertiert die Variablen MIN1 und MAX1 vom Datentyp „Datumzeit“ auf den Typ „Zeichen“. Der Datentyp „Zeichen“ wird benötigt, um die Variableninhalte als Textzeichenfolge in einem Dialogfeld darzustellen.

MIN1 und MAX1 sind Systemvariablen, die automatisch durch den Befehl STATISTICS erstellt werden. Sie beinhalten die ältesten und aktuellsten Datumswerte des von Ihnen ausgewählten Datumsfelds.
ALLTRIM( ) Löscht zusätzliche Leerzeichen vor und nach dem ältesten und aktuellsten Datumswert, sobald diese im Dialogfeld angezeigt werden.
CTOD( )

Konvertiert die Variablen v_Startdatum und v_Enddatum vom Datentyp „Zeichen“ auf den Typ „Datumzeit“. Der Datentyp „Datumzeit“ wird benötigt, um Datumswerte voneinander abziehen und miteinander vergleichen zu können.
CTOD( ) Konvertiert die Variablen v_Startdatum und v_Enddatum vom Datentyp „Zeichen“ auf den Typ „Datumzeit“, damit sie dem Datentyp der Variable v_Datumsfeld entsprechen. Alle Parameter der Funktion BETWEEN müssen denselben Datentyp aufweisen.
BETWEEN( ) Filtert das Datumsfeld auf Basis des von Ihnen festgelegten Start- und Enddatums.
MONTH( ) Extrahiert den Monatsbestandteil aus jedem Datum des Datumsfelds als eine Zahl.
CMOY( ) Extrahiert den Monatsbestandteil aus jedem Datum des Datumsfelds als einen Zeichenwert.

Beispielskript: Filtert Datensätze nach Datum und gruppiert die gefilterten Datensätze nach Monaten.

COMMENT
Das Skript ermöglicht Ihnen, einen Datumsfilter auf eine beliebige Analytics-Tabelle mit einem Datumsfeld anzuwenden und die durch den Filter berücksichtigten Datensätze dann nach Monaten zu gruppieren.
END

COMMENT Fordert Sie auf, eine Tabelle im Analytics-Projekt auszuwählen.
ACCEPT "Wählen Sie eine Tabelle mit einem Datumsfeld aus:" FIELDS "xf" TO v_Tabellenname

COMMENT Öffnet die ausgewählte Tabelle.
OPEN %v_Tabellenname%

COMMENT Fordert Sie auf, ein Datumsfeld aus der Tabelle auszuwählen.
ACCEPT "Wählen Sie ein Datumsfeld aus:" FIELDS "D" TO v_Datumsfeld

COMMENT Identifiziert die ältesten und aktuellsten Datumswerte des ausgewählten Datumsfelds.
STATISTICS ON %v_Datumsfeld%

COMMENT Weist die ältesten und aktuellsten Datumswerte Variablen zu. Die Variablen werden verwendet, um die bestehende Datumsspanne im Dialogfeld anzuzeigen, in dem Sie das Start- und Enddatum des Datumsfilters festlegen. Es ist einfacher, Datumswerte für den Filter festzulegen, wenn Sie die bestehende Datumsspanne kennen.
ASSIGN v_Mindestdatum = ALLTRIM(DATE(MIN1; "JJJJMMTT"))
ASSIGN v_Höchstdatum = ALLTRIM(DATE(MAX1; "JJJJMMTT"))

COMMENT Fordert Sie auf, das Start- und Enddatum des Datumsfilters festzulegen.
DIALOG (DIALOG TITLE "Benutzerdialog" WIDTH 484 HEIGHT 153 ) (BUTTONSET TITLE "&OK;&Abbrechen" AT 370 12 DEFAULT 1 ) (TEXT TITLE "Geben Sie ein Startdatum an:" AT 12 16 ) (EDIT TO "v_Startdatum" AT 156 12 DEFAULT "JJJJMMTT" ) (TEXT TITLE "Geben Sie ein Enddatum an.:" AT 12 52 ) (EDIT TO "v_Enddatum" AT 156 48 DEFAULT "JJJJMMTT" ) (TEXT TITLE "Datumsbereich in Tabelle:" AT 12 88 ) (TEXT TITLE "%v_Mindestdatum%   bis  %v_Höchstdatum%" AT 156 88 )

COMMENT Zeigt eine Warnung an, falls der benutzerdefinierte Datumsfilter mehr als ein Jahr umfasst.
IF CTOD(v_Enddatum) - CTOD(v_Startdatum) > 365 OR CTOD(v_Startdatum) - CTOD(v_Enddatum) > 365 DIALOG (DIALOG TITLE "Benutzerdialog" WIDTH 469 HEIGHT 100 ) (BUTTONSET TITLE "&OK;&Abbrechen" AT 348 8 DEFAULT 1 ) (TEXT TITLE "Der Datumsbereich überschreitet ein Jahr Monatsgruppierungen könnten Datensätze aus mehr als einem Jahr beinhalten." AT 12 28 WIDTH 326 HEIGHT 33 ) (TEXT TITLE "Vorsicht" AT 12 8 )

COMMENT Zeigt eine Warnung an, falls das benutzerdefinierte Startdatum hinter dem Enddatum liegt.
IF CTOD(v_Startdatum) > CTOD(v_Enddatum) DIALOG (DIALOG TITLE "Benutzerdialog" WIDTH 469 HEIGHT 100 ) (BUTTONSET TITLE "&OK;&Abbrechen" AT 348 8 DEFAULT 1 ) (TEXT TITLE "Das Startdatum liegt nach dem Entdatum. Datensätze zwischen den beiden Datumswerten werden berücksichtigt." AT 12 28 WIDTH 326 HEIGHT 33 ) (TEXT TITLE "Vorsicht" AT 12 8 )

COMMENT Wendet den Datumsfilter auf die Tabelle und das von Ihnen gewählte Feld an.
SET FILTER TO BETWEEN(%v_Datumsfeld%; CTOD(%v_Startdatum%); CTOD(%v_Enddatum%))

COMMENT Fordert Sie auf, ein Zwischensummenfeld auszuwählen.
ACCEPT "Wählen Sie ein numerisches Feld aus, für das in jedem Monat eine Zwischensumme berechnet werden soll:" FIELDS "N" TO v_Zwischensummenfeld

COMMENT Gruppiert die Tabelle nach Monaten und gibt die Ergebnisse in eine neue Tabelle aus.
SUMMARIZE ON MONTH(%v_Datumsfeld%) SUBTOTAL %v_Zwischensummenfeld% OTHER CMOY(%v_Datumsfeld%, 9) TO „%v_Tabellenname%_nach_Monat.FIL" OPEN PRESORT

Wie geht es weiter?

Herzlichen Glückwunsch, falls Sie alle Tutorials in Wie Funktionen verwendet werden und in Fortgeschrittene Verwendung von Funktionen abgeschlossen haben! Sie haben nun eine gute Übersicht, wie Analytics-Funktionen in der gesamten Analytics-Software funktionieren.

Es folgen einige Vorschläge, wie Sie noch mehr über Funktionen erfahren können:

  • Setzen Sie Ihre Erkundigungen fort
    • Unter Wichtigste 30 Analytics-Funktionen finden Sie eine Liste der am häufigsten verwendeten Analytics-Funktionen und zugehörige Beispiele.
    • Mit Analytics-Funktionen suchen und filtern enthält zahlreiche Beispiele für die Verwendung von Analytics-Funktionen, um in Tabellen eine leistungsfähige sowie effektive Datensuche und Datenfilterung durchzuführen.
    • Durchsuchen Sie alle Analytics-Funktionen Funktionen. Machen Sie sich auf abstrakter Ebene mit allen unterschiedlichen Möglichkeiten vertraut, die Funktionen bieten.
  • Verlieren Sie Funktionen nicht aus den Augen

    Wenn Sie im Rahmen Ihrer Arbeit mit Analytics eine Datenanalyse durchführen müssen, fragen Sie sich immer zuerst: „Könnte mir eine Funktion dabei helfen? Oder vielleicht mehrere Funktionen zusammen?“

    Bei Datenanalysen mit Analytics-Befehlen besteht die Schwierigkeit oft zum großen Teil in der Vorbereitung der Daten auf die Analyse. Eine einzelne Funktion oder mehrere Funktionen gemeinsam sind für die Datenvorbereitung oft kritisch.